SCCM-TOOLS.COM - Right Click - Add Computer to Collection

Add Computer to Collection

This tools has two parts. It will allow you to add a computer to multiple collections or mulitple computers to a single collection. This will also give you the ability to right click on a computer in a query as well.

Download

Code

------------------addcomps.hta----------------------
<head>
<title>Add computers to Collection</title>
<body background = "background.jpg">

<HTA:APPLICATION
      ID="Addcompcol"
     APPLICATIONNAME="Addcomputer"
     SCROLL="NO"
     SINGLEINSTANCE="yes"
     WINDOWSTATE="normal"
     SYSMENU="no"
>

</head>
<script language="VBScript">
'Created by Matthew Hudson
   ''' addcomps.hta COLLECTIONid     addcomps.hta SMS00001
  Sub Closeme
    window.close()
  end sub

Sub Window_Onload
  window.moveTo 200,200
  window.resizeto 250,275
   'width x height

end sub

</script>

<body onload=Window_Onload>
<script language="VBScript">
On error resume next
Set Shell = CreateObject("Wscript.Shell")
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set SWbemLocator=CreateObject("WbemScripting.SWbemLocator")
set SWbemServices = SWbemLocator.ConnectServer("SMSserver","root\SMS\site_XXX")
   If Err.Number Then
        Err.Clear
        Closeme()
    End If
sub search()
     count=0
     if findcomp.value <> "" Then
        strQuery = "select * from SMS_CM_RES_COLL_SMS00001 where name like '%"& findcomp.value &"%'"
        Set Computers= SWbemServices.ExecQuery(strQuery)

strHTML= strHTML & "<select size=""6"" name=""Computerlisting"" multiple style=""width:200"">"

for each Computer in Computers
           count=count+1

if count<50 then
            ' strHTML= strHTML & "<BR>" & Computer.Name
                 ' msgbox Computer.ResourceID

strHTML= strHTML & "<option value="& Computer.ResourceID  &">"& Computer.Name &"</option>"

End if
        Next
       strHTML= strHTML & "</select>"
       strHTML= strHTML &  "<input type=""button"" value=""Add computers name""  onClick=""addcomputers"">"

Output.InnerHTML = strHTML
     End if
end sub

sub addcomputers()

''''''''
    CollectionID = split(Addcompcol.commandLine, chr(34))
    collectionquery = "SMS_Collection.CollectionID='"&Trim(CollectionID(2))&"'"
   ' msgbox collectionquery
    Set oCollection = SWbemServices.Get(collectionquery)

''''''''
For Each Computerselect in Computerlisting.Options
      if Computerselect.Selected then

Set newDirectRule = SWbemServices.Get("SMS_CollectionRuleDirect").SpawnInstance_
         newDirectRule.ResourceClassName = "SMS_R_System"
         newDirectRule.ResourceID = Computerselect.value ' this is the resource value of the computer selected
         ' Add the new query rule to a variable.
         Set oCollectionRule = newDirectRule
         oCollection.AddMembershipRule oCollectionRule
       end if
    Next

''''''''''
   oCollection.RequestRefresh True
   strHTML="Computer(s) added!"
   Output.InnerHTML = strHTML
end Sub

</script>
<input type="value" style="background-color:#ffb7d6" name="findcomp" size="20" >
<input type="button" value="OK" name="acceptcomp"  onClick="search" style="background:red; ">
<BR>
<hr>
<span id="Output"></span>

--------------------------------------

------------------addtocollections.hta----------------------
<head>
<title>Add computer to Collection(s)</title>
<body>

<HTA:APPLICATION
      ID="Addcol"
     APPLICATIONNAME="Addcomputer"
     SCROLL="NO"
     SINGLEINSTANCE="yes"
     WINDOWSTATE="normal"
     SYSMENU="no"
>

</head>
<script language="VBScript">
'Created by Matthew Hudson
   ''' addcomps.hta Resourceid     addcomps.hta 4
  Sub Closeme
    window.close()
  end sub

Sub Window_Onload
  window.moveTo 200,200
  window.resizeto 315,275
   'width x height

end sub

</script>

<body onload=Window_Onload>
<script language="VBScript">
On error resume next
Set Shell = CreateObject("Wscript.Shell")
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set SWbemLocator=CreateObject("WbemScripting.SWbemLocator")
set SWbemServices = SWbemLocator.ConnectServer("SMSserver","root\SMS\site_XXX")
   If Err.Number Then
        Err.Clear
        Closeme()
    End If
sub search()
     count=0
     if findcomp.value <> "" Then
        strQuery = "select * from SMS_Collection where name like '%"& findcomp.value &"%'"
        Set Collections= SWbemServices.ExecQuery(strQuery)

strHTML= strHTML & "<select size=""6"" name=""Collectionlisting"" multiple style=""width:300"">"

for each Collection in Collections
           count=count+1

if count<50 then
            ' strHTML= strHTML & "<BR>" & Computer.Name
                 ' msgbox Computer.ResourceID

strHTML= strHTML & "<option value="& Collection.CollectionID  &">"& Collection.Name &"</option>"

End if
        Next
       strHTML= strHTML & "</select>"
       strHTML= strHTML &  "<input type=""button"" value=""Add to Collections""  onClick=""addcomputers"">"

Output.InnerHTML = strHTML
     End if
end sub

sub addcomputers()

''''''''
    ResourceID = split(Addcol.commandLine, chr(34))

''''''''
For Each Collectionselect in Collectionlisting.Options
      if Collectionselect.Selected then
         collectionquery = "SMS_Collection.CollectionID='"&Trim(Collectionselect.value)&"'"
         Set oCollection = SWbemServices.Get(collectionquery)
         Set newDirectRule = SWbemServices.Get("SMS_CollectionRuleDirect").SpawnInstance_
         newDirectRule.ResourceClassName = "SMS_R_System"
         newDirectRule.ResourceID = ResourceID(2) ' this is the resource value of the computer selected
         ' Add the new query rule to a variable.
         Set oCollectionRule = newDirectRule
         oCollection.AddMembershipRule oCollectionRule
       end if
   Next
''''''''''
   oCollection.RequestRefresh True
   strHTML="Computer has been added!"
   Output.InnerHTML = strHTML
end Sub

--------------------------------------

Documentation

You will need to possible create the Extensions folder, Actions folder, as well as the guids.  The folder path should look
like the path below

x:\Program Files\Microsoft Configuration Manager\AdminUI\XmlStorage\Extensions\
Actions\7ba8bf44-2344-4035-bdb4-16630291dcf6
Copy the 2 files:
   addcomps.hta
   addtocollections.hta
To a programs folder somewhere and edit the file path in the xml documents.

The program will give you two ways to add computers to a collection.

1. Right click a collection and add multiple computers
2. Right click a computer and it to multiple collections.

Both scripts use a LIKE clause so you can type in adobe and find all the adobe collections.  The applies for the computer name.  Since our computers are based on
numeric asset tags we can type in the last 4 or 5 digits and find the computer.
--------------------------------
Configuring the application

a.  You will need to modify both HTA files and replace the  following line
        set SWbemServices = SWbemLocator.ConnectServer("SMSserver","root\SMS\site_XXX")
SMSserver - replace with your SCCM server name
site_XXX - replace XXX your Site Code

b. If this is running from a remote console then it might be necessary to pass a user name and password.  Please
refer to the documentation below.
http://msdn.microsoft.com/en-us/library/aa393720(VS.85).aspx

GUIDs
----------------------------
7ba8bf44-2344-4035-bdb4-16630291dcf6 - Computer in a collection
716f8f86-5c3e-448d-baa2-8d2763fa8e7a - Computer in a query
dbb315c3-1d8b-4e6a-a7b1-db8246890f59 - Collection
fa922e1a-6add-477f-b70e-9a164f3b11a2 - Collection

--Created by: Matthew Hudson